<!--METADATA TYPE="typelib" UUID="CD000000-8B95-11D1-82DB-00C04FB1625D" NAME="CDO for Windows 2000 Library" -->
<!--METADATA TYPE="typelib" UUID="00000205-0000-0010-8000-00AA006D2EA4" NAME="ADODB Type Library" -->

<%
Sub SendMailMsg(strFrom, strRecipient, strBcc, strSubject, strBody, bHTML)
	Dim objMail
	Dim objConfig
	
	Set objMail = Server.CreateObject("CDO.Message")
	
	Set objConfig = Server.CreateObject("CDO.Configuration")
	objConfig.Fields(cdoSendUsingMethod) = cdoSendUsingPort
	objConfig.Fields(cdoSMTPServer)="smtp.1and1.com"
	objConfig.Fields(cdoSMTPServerPort) = 25
	objConfig.Fields.Update
	
	Set objMail.Configuration = objConfig 
	
	If strFrom = "" Then
		strFrom = "info@aroundhouston.com"
	End If

	objMail.Sender = strFrom
	objMail.From = strFrom
	objMail.To = strRecipient
	objMail.Bcc = strBcc
	objMail.Subject = strSubject
	
	If bHTML Then
		objMail.HTMLBody = strBody
	Else
		objMail.TextBody = strBody
	End If
	
	On Error Resume Next
	
	objMail.Send
	
	Set objMail = Nothing
	Set objConfig = Nothing 
End Sub


'''''''' The following is not used ''''''''''''''''''''''

Sub SendMailMsg_OLD(strFrom, strRecipient, strBcc, strSubject, strBody, bHTML)
	dim objMail

	Set objMail = CreateObject("CDONTS.NewMail")
	
	If strFrom = "" Then
		strFrom = "info@aroundhouston.com"
	End If
	
	With objMail
		.From = strFrom
		.To = strRecipient
		.Bcc = strBcc
		.Subject = strSubject
		.Body = strBody
		If bHTML Then
			objMail.BodyFormat = CdoBodyFormatHTML
			objMail.MailFormat = CdoMailFormatMime
		End If
		.Importance = cdoNormal
		.Send
	End With
	Set objMail = nothing
End Sub
%>